Процедуры и функции. Процедура представляет собой последовательность инструкций VB, которая выполняет действия, но не возвращает значение

Процедуры и функции являются основными структурными элементами программных модулей проектов VB и выполняют действия, предусмотренные разработчиком в соответствии с назначением программы.

Процедура представляет собой последовательность инструкций VB, которая выполняет действия, но не возвращает значение. Процедура может получать аргументы, как например константы, переменные, или выражения, передаваемые ей вызывающей процедурой.

Функция представляет собой последовательность инструкций VB, однако в отличие от процедуры она возвращает значения. Возврат значения осуществляется путем его присвоения имени функции в одной или нескольких инструкциях процедуры.

Отдельный модуль VB может содержать произвольное количество процедур и функций.

Определения процедур записываются в следующем виде (квадратные скобки означают возможность опускания элемента описания):

[Private | Public] [Static] Sub <Имя> ([Список аргументов])

[Инструкции]

[Exit Sub]

[Инструкции]

End Sub

Определения функций записываются в следующем виде:

[Public | Private] [Static] Function <Имя> ([Список аргументов]) [As <Тип>]

[Инструкции]

[<Имя> = выражение]

[Exit Function]

[Инструкции]

[<имя> = выражение]

End Function

Описание функции от описания процедуры отличается только ключевым словом (Function вместо Sub), указанием типа возвращаемого значения ([As <тип>]) и оператором возврата значения [<имя> = выражение]. Рассмотрим назначение элементов описания функций и процедур (табл. 12).

Таблица 12

Элементы синтаксиса функций и процедур

Элемент	Описание
Public	Указывает, что процедура (функция (ф)) доступна для всех других процедур (ф) во всех модулях. Используется по умолчанию
Private	Указывает, что процедура (ф) доступна для других процедур (ф) только того модуля, в котором она описана
Static	Необязательный. Указывает, что переменные процедуры (ф) сохраняются в промежутках времени между вызовами этой процедуры. Атрибут Static не действует на переменные, описанные вне процедуры (ф), даже если они используются в этой процедуре
Имя	Имя процедуры (ф)
Список аргументов	Список переменных, представляющий аргументы, которые передаются в процедуру (ф) при ее вызове. Имена переменных разделяются запятой
Инструкции	Любая группа инструкций (операторов), выполняемых внутри процедуры (ф).
Exit	Инструкция, прекращающая выполнение процедуры (ф).

 

Аргумент [Список аргументов] имеет следующий синтаксис и элементы (табл. 13):

[Optional] [ByVal | ByRef] [ParamArray] <Имя переменной> [As <тип>] [= По умолчанию]

Таблица 13

Элементы синтаксиса списка аргументов процедур и функций

Элемент	Описание
Optional	Указывает, что этот аргумент необязателен
ByVal	Указывает, что этот аргумент передается по значению, то есть передается только копия значения переменной, служащей в качестве аргумента. Это означает, что переменная не может быть изменена в использующей ее процедуре (ф)
ByRef	Указывает, что этот аргумент передается по ссылке, то есть передается адрес расположения переменной, служащей в качестве аргумента. Это означает, что переменная может быть изменена в использующей ее процедуре (ф). Описание ByRef используется в VB по умолчанию
ParamArray	Используется только в качестве последнего элемента в списке [Список аргументов] для указания, что конечным аргументом является описанный как Optional массив типа Variant. Ключевое слово ParamArray позволяет задавать произвольное количество аргументов. Оно не может быть использовано с ключами ByVal, ByRef или Optional
Имя переменной	Имя переменной
Тип	Тип данных переменной
По умолчанию	Любая константа или выражение, дающее константу. Используется только вместе с параметром Optional для передачи значения по умолчанию при опускании параметра при вызове процедуры (ф)

 

Чтобы вызвать процедуру Sub из другой процедуры, следует указать имя этой процедуры и значения для всех требуемых аргументов через запятую в скобках или без них.

Sub proc1() ' Объявление вызывающей процедуры proc1

proc2 "Привет!"

' Вызов процедуры по имени proc2 с передачей ей

' параметра – строки "Привет!"

End Sub ' Завершение объявления процедуры proc1

Sub proc2(par As String)

' Объявление вызываемой процедуры proc2, принимающей

' один параметр типа String (строка)

MsgBox par

' Отображение значения параметра, переданного в процедуру

End Sub ' Завершение объявления процедуры proc2

При использовании инструкции Call перед именем процедуры аргументы должны быть заключены в скобки. Для предыдущего примера:

Call proc2("Привет!")

Чтобы получить возвращаемое значение функции, надо указать ее имя, после которого в скобках ввести параметры, заданные в соответствии с определением функции.

Sub proc3()' Объявление вызывающей процедуры proc3

MsgBox kvadrat(2.3)

' Отображение значения, возвращаемого вызываемой функцией

' kvadrat, в которую передается число 2.3

End Sub ' Завершение объявления процедуры proc1

Function kvadrat(par As Double) As Double

' Объявление функции по имени kvadrat, возвращающей

' вещественное число и принимающей один

' вещественный параметр

kvadrat = par ^ 2

' Запись рассчитанного значения в функцию kvadrat

' для возврата его в месте вызова функции (kvadrat)

End Function ' Завершение объявления функции

Если возвращаемое значение функции не требуется, можно вызвать функцию точно так же, как процедуру Sub. Надо указать имя функции, опустить скобки и указать список аргументов. Для предыдущего примера:

kvadrat 2.3

Если процедура (ф) не имеет аргументов, инструкция объявления Sub или Function должна содержать пустые скобки.

При вызове процедур (ф) предполагается позиционная передача аргументов, т.е. в порядке следования в описании. Возможна также передача аргументов по именам, вне зависимости от их позиции в описании процедуры (ф).

Sub mycall()

mymsg "qwerty", 1234

' Вызов процедуры с передачей параметров по порядку

mymsg mykey:=1234, mystr:="qwerty"

' Вызов процедуры с передачей параметров по их именам

End sub

Sub mymsg(mystr As String, mykey As Integer)

' Объявление процедуры, принимающей параметр по имени

' mystr типа String (строка) и параметр по имени mykey

' типа Integer (целое число)

MsgBox mystr & " " & mykey

End Sub

Проверить отсутствие необязательного параметра (отмеченного ключом Optional) можно с помощью функции IsMissing, возвращающей значение True (Истина), если опускаемый аргумент отсутствует.

Sub CallDemo() ' Вызывающая процедура

DemoArg 10, 5

' Вызов процедуры DemoArg с передачей двух параметров

DemoArg 12

' Вызов процедуры DemoArg с передачей одного праметра

End Sub

Sub DemoArg(I As Integer, Optional J)

' Вызываемая процедура

If IsMissing(J) Then J = 10

' При отсутствии параметра J в вызове процедуры DemoArg

' параметру J присваивается 10

I = I + J

MsgBox "I=" & I

End Sub

Не допускается определение процедуры (ф) внутри другой процедуры (ф).

В случае, если процедура (ф) должна быть доступна из процедур (ф), находящихся в других модулях перед ключевым словом ее объявления Sub или Function ставится инструкция Public:

Модуль Module1

Sub proc1() ' Описание процедуры proc1 в модуле Module1

proc2 "Ура!"

' Вызов процедуры proc2, описанной в другом модуле

End Sub

Модуль Module2

Public Sub proc2(p1 As String)

' Описание процедуры proc2 в модуле Module2

MsgBox UCase(p1)

End Sub